全局量子和查找窗體的方法都用過，不太好，用下面這個(gè)

unit once;
interface

uses
 Windows ,Messages, SysUtils, Classes, Forms;

implementation

const
 STR_UNIQUE    = '{2BE6D96E-827F-4BF9-B33E-8740412CDE96}';
 MI_ACTIVEAPP  = 1;  {激活應(yīng)用程序}
 MI_GETHANDLE  = 2;  {取得句柄}

var
 iMessageID    : Integer;
 OldWProc      : TFNWndProc;
 MutHandle     : THandle;
 BSMRecipients : DWORD;

function NewWndProc(Handle: HWND; Msg: Integer; wParam, lParam: Longint):
 Longint; stdcall;
begin
 Result := 0;
 if Msg = iMessageID then
 begin
   case wParam of
     MI_ACTIVEAPP: {激活應(yīng)用程序}
       if lParam<>0 then
       begin
         {收到消息的激活前一個(gè)實(shí)例}
         {為什么要在另一個(gè)程序中激活?}
         {因?yàn)樵谕粋€(gè)進(jìn)程中SetForegroundWindow并不能把窗體提到最前}
         if IsIconic(lParam) then
           OpenIcon(lParam)
         else
           SetForegroundWindow(lParam);
         Application.Terminate; {終止本實(shí)例}
       end;
     MI_GETHANDLE: {取得程序句柄}
       begin
         PostMessage(HWND(lParam), iMessageID, MI_ACTIVEAPP,
           Application.Handle);
       end;
   end;
 end
 else
   Result := CallWindowProc(OldWProc, Handle, Msg, wParam, lParam);
end;
 
procedure InitInstance;
begin
 {取代應(yīng)用程序的消息處理}
 OldWProc    := TFNWndProc(SetWindowLong(Application.Handle, GWL_WNDPROC,
   Longint(@NewWndProc)));

 {打開互斥對(duì)象}
 MutHandle := OpenMutex(MUTEX_ALL_ACCESS, False, STR_UNIQUE);
 if MutHandle = 0 then
 begin
   {建立互斥對(duì)象}
   MutHandle := CreateMutex(nil, False, STR_UNIQUE);
 end
 else begin
   Application.ShowMainForm  :=  False;
   {已經(jīng)有程序?qū)嵗?廣播消息取得實(shí)例句柄}
   BSMRecipients := BSM_APPLICATIONS;
   BroadCastSystemMessage(BSF_IGNORECURRENTTASK or BSF_POSTMESSAGE,
       @BSMRecipients, iMessageID, MI_GETHANDLE,Application.Handle);
 end;
end;

initialization
 {注冊(cè)消息}
 iMessageID  := RegisterWindowMessage(STR_UNIQUE);
 InitInstance;

finalization
 {還原消息處理過程}
 if OldWProc <> Nil then
   SetWindowLong(Application.Handle, GWL_WNDPROC, LongInt(OldWProc));

 {關(guān)閉互斥對(duì)象}
 if MutHandle <> 0 then CloseHandle(MutHandle);

end.

將這個(gè)unit加入項(xiàng)目，主窗體引用即可！delphi7+winxp下測(cè)試通過